* AMPLIFIER DESIGN 
* AC BODE & NOISE ANALYSIS         
*******************************************
*  DEVICE MODELS
.INCLUDE TIModel5V1um  NOPRINT
*  ANALYSIS
.OPTIONS NUMDGT=12 LVLSUB=0 TOL=10N OP DCNODE
+ CAPMAX=1 DISPFREQ=0 
.AC DEC 100 1 1G
.NOISE V(OUT) VIN 100
.PRINT AC VDB(OUT) VP(OUT) 
.PUNCH AC VDB(OUT) VP(OUT) 
.PRINT NOISE INOISE ONOISE
.PUNCH NOISE INOISE ONOISE
*  SOURCES
VDD  VDD 0  DC   5V
VSS  VSS 0  DC   0V
VGD  GND 0  DC   2.5V
*
VIN INP 0 DC 2.5V AC 1
*  ANALYSIS NETWORK
LF OUT INM  1G
CF INM  0   1M
*  LOAD
CL  OUT GND  10P
*  MAIN CIRCUIT  
*
.INCLUDE  AmpNetlist.Filename
*
.END
************************************************
*
************************************************
* PSRR ANALYSIS FOR AMP        
*******************************************
*  DEVICE MODELS
.INCLUDE TIModel5V1um  NOPRINT
*  ANALYSIS
.OPTIONS NUMDGT=12 LVLSUB=0 TOL=10N OP DCNODE
+ DISPFREQ=0 
.AC DEC 100 1 100MEG
.PRINT AC VDB(OUT)  
.PUNCH AC VDB(OUT) 
*  SOURCES
VDD  VDD 0  DC   5V  AC 1
VSS  VSS 0  DC   0V
VGD  GND 0  DC   2.5V
*        
VIN INP 0 DC 2.5V 
*  ANALYSIS NETWORK
RF  INM OUT  1
*  LOAD
CL  OUT GND  10P
*  MAIN CIRCUIT  
*
.INCLUDE  AmpNetlist.Filename
*
.END
************************************************
*
************************************************
* SINE WAVE ANALYSIS FOR THD    
**********************************************
*  DEVICE MODELS
.INCLUDE TIModel5V1um NOPRINT  
*  ANALYSIS
.OPTIONS NUMDGT=12 LVLSUB=0 TOL=10N OP DCNODE
+ DISPFREQ=0 
.TRAN 500NS 16MS FOUR_FREQ=1K FOUR_NCOEFF=12
.FOUR  V(OUT POS) 
.PUNCH TR V(OUT POS)
*  SOURCES
VDD  VDD  0  DC  5V
VSS  VSS  0  DC  0V
VAG  GND  0  DC  2.5V
*
VIN  POS  0  SIN 2.5V 1.75V 1KHZ
VPP  INP  0  DC  2.5V
*
*  FEEDBACK NETWORK
RF  INM  OUT  1G
CF  INM  OUT  1P
RI  INM  POS  1G
CI  INM  POS  1P
*
*  LOAD NETWORK
CL OUT GND 10P 
*
*  MAIN CIRCUIT
.INCLUDE  AmpNetlist.Filename
*
.END
************************************************
*
************************************************
* STEP RESPONSE FOR SLEW RATE AND SETTLING    
**********************************************
*  DEVICE MODELS
.INCLUDE TIModel5V1um NOPRINT  
*  ANALYSIS
.OPTIONS NUMDGT=12 LVLSUB=0 TOL=10N OP DCNODE
+ DISPFREQ=0 
.TRAN 1NS 1US  
.PUNCH TR V(OUT INP)
*  SOURCES
VDD  VDD  0  DC  5V
VSS  VSS  0  DC  0V
VAG  GND  0  DC  2.5V
*
VIN  INP  0  PWL 0S 2V 8NS 2V 10NS 3V 508NS 3V 510NS 2V 1US 2V 
*
*  FEEDBACK NETWORK
RF  INM  OUT  1
*
*  LOAD NETWORK
CL OUT GND 10P 
*
*  MAIN CIRCUIT
.INCLUDE  AmpNetlist.Filename
*
.END