* HW#2 BANDGAP VOLTAGE REFERENCE FOR CLASS EE7329-501
* TEMPERATURE ANALYSIS                    
*****************************************************
*  DEVICE MODELS
.INCLUDE  TISpiceNPN     NOPRINT
.INCLUDE  TISpicePNP     NOPRINT
.INCLUDE  TIModel5V1um   NOPRINT
*  ANALYSIS
.OPTIONS NUMDGT=8 TOL=1N OP DCNODE 
.DC TEMP -40 125 5 
.PRINT DC V(BG)  
.PUNCH DC V(BG)  
*  SOURCES
VCC VCC 0  DC   5V
VEE VEE 0  DC   0V 
*
*  MAIN CIRCUIT
Q1  N11 BG  N1   NPN_AE64  AREA=63.98 M=1
Q2  N12 BG  N2   NPN_AE64  AREA=63.98 M=9
Q3  N5  N6  N4   NPN_AE64  AREA=63.98 M=3
Q4  N6  N5  VEE  NPN_AE64  AREA=63.98 M=1
Q5  N9  N8  N5   NPN_AE64  AREA=63.98 M=1
Q6  N8  N8  N6   NPN_AE64  AREA=63.98 M=3
Q7  N15 N15 N16  NPN_AE64  AREA=63.98 M=1
Q8  VCC N14 BG   NPN_AE64  AREA=63.98 M=1
Q9  VCC N10 N14  NPN_AE8   AREA=7.98  M=1
Q10 N15 N11 N10  PNP_AE32  AREA=31.99 M=2
Q11 N11 N12 N10  PNP_AE32  AREA=31.99 M=1
Q12 N12 N12 N10  PNP_AE32  AREA=31.99 M=1
Q13 N8  N18 N7   PNP_AE2   AREA=1.995 M=1
Q14 N18 N18 VCC  PNP_AE8   AREA=7.98  M=1
M1  N10 N9  VCC VCC PCH W=25 L=25 M=4 AD=#3*W# AS=AD PD=#2*W+6# PS=PD
M2  N9  N9  VCC VCC PCH W=25 L=25 M=1 AD=#3*W# AS=AD PD=#2*W+6# PS=PD
M3  N8  N9  VCC VCC PCH W=25 L=25 M=1 AD=#3*W# AS=AD PD=#2*W+6# PS=PD
R1  N1  N2  3550  TC=1E-4
R2  N1  VEE 17300 TC=1E-4
R4  N4  VEE 3550  TC=1E-4
R5  BG  VEE 12K   TC=1E-4
R6  N16 VEE 17K   TC=1E-4
R7  N7  VCC 5K    TC=1E-4
R8  N18 VEE 200K  TC=1E-4
CC  N11 VEE 10P
*
.END