* HW#3 FOR CLASS EE7329-501
* DIFFERENTIAL AMP ANALYSIS; OP, AC, NOISE
* DIFFERENTIAL AMP OPEN LOOP                   
******************************************
*  DEVICE MODELS
.INCLUDE TIModel3Vp6um   NOPRINT
*  ANALYSIS
.OPTIONS NUMDGT=8 LVLSUB=0 TOL=1N OP DCNODE
+ DISPFREQ=0
.AC DEC 100 1 1G
.NOISE V(OUTP,OUTM) VIN 1000
.PRINT AC VDB(OUTP,OUTM) VP(OUTP,OUTM) 
.PUNCH AC VDB(OUTP,OUTM) VP(OUTP,OUTM)
.PRINT NOISE INOISE ONOISE
.PUNCH NOISE INOISE ONOISE
*  SOURCES
VDD  VDD 0  DC   3V
VSS  VSS 0  DC   0V
VMID VCM 0  DC   1.5V  
*        
IBIAS VDD IB  DC  10UA
*
VIN INP INM DC 0V AC 1 
RCM1 INM VCM 1
RCM2 INP VCM 1
*  LOAD/COMPENSATION
RL1 OUTM VCM 50K
RL2 OUTP VCM 50K
CL1 OUTM VCM 5PF
CL2 OUTP VCM 5PF
*  MAIN CIRCUIT
.INCLUDE Amp.sch
*
.END
*******************************************
*******************************************
* HW#3 FOR CLASS EE7329-501
* SINE WAVE ANALYSIS FOR THD AND OUTPUT SWING     
* AMP CLOSED-LOOP, INVERTING GAIN=2
********************************************
*  DEVICE MODELS
.INCLUDE TIModel3Vp6um   NOPRINT
*  ANALYSIS
.OPTIONS NUMDGT=8 LVLSUB=0 TOL=1N OP DCNODE
+ DISPFREQ=0 
.TRAN 500NS 10MS FOUR_FREQ=1K FOUR_NCOEFF=12
.FOUR  V(OUTP,OUTM POS,NEG) 
.PUNCH TR V(OUTP,OUTM POS,NEG)
*  SOURCES
VDD  VDD 0  DC   1.5V
VSS  VSS 0  DC  -1.5V
VMID VCM 0  DC     0V 
*
IBIAS VDD IB  DC  10UA
*
VIN POS NEG DC 0V SIN 0V 1.25V 1KHZ
RCM1 NEG VCM 1
RCM2 POS VCM 1
*
*  GAIN NETWORK
RI1 NEG INM  10K
RI2 POS INP  10K
RF1 INM OUTP 20K
RF2 INP OUTM 20K
*  LOAD/COMPENSATION
RL1 OUTM VCM 50K
RL2 OUTP VCM 50K
CL1 OUTM VCM 5PF
CL2 OUTP VCM 5PF
*  MAIN CIRCUIT
*
.INCLUDE Amp.sch
*
.END
*******************************************
*******************************************
* HW#3 FOR CLASS EE7329-501
* SMALL-SIGNAL SETTLING TRANSIENT ANALYSIS      
* AMP CLOSED-LOOP, INVERTING GAIN=1
********************************************
*  DEVICE MODELS
.INCLUDE TIModel3Vp6um   NOPRINT
*  ANALYSIS
.OPTIONS NUMDGT=8 LVLSUB=0 TOL=1N OP DCNODE
+ DISPFREQ=0 
.TRAN 1NS 1US 
.PUNCH TR V(OUTP,OUTM POS,NEG)
*  SOURCES
VDD  VDD 0  DC   1.5V
VSS  VSS 0  DC  -1.5V
VMID VCM 0  DC     0V 
*
IBIAS VDD IB  DC  10UA
*
VIN POS NEG DC 0V PWL 0S 0V 1NS 0V 5NS 100MV 1US 100MV
RCM1 NEG VCM 1
RCM2 POS VCM 1
*
*  GAIN NETWORK
RI1 NEG INM  10K
RI2 POS INP  10K
RF1 INM OUTP 10K
RF2 INP OUTM 10K
*  LOAD/COMPENSATION
RL1 OUTM VCM 50K
RL2 OUTP VCM 50K
CL1 OUTM VCM 5PF
CL2 OUTP VCM 5PF
*  MAIN CIRCUIT
*
.INCLUDE Amp.sch
*
.END