* AUDIO POWER AMPLIFIER DESIGN 
* AC BODE & NOISE ANALYSIS         
*******************************************
*  DEVICE MODELS
.INCLUDE TIModel3Vp6um  NOPRINT
*  ANALYSIS
.OPTIONS NUMDGT=12 LVLSUB=0 TOL=1U OP DCNODE
+ DISPFREQ=0 
.AC DEC 100 1M 1G
.NOISE V(OUT) VIN 100
.PRINT AC VDB(OUT) VP(OUT) 
.PUNCH AC VDB(OUT) VP(OUT) 
.PRINT NOISE INOISE ONOISE
.PUNCH NOISE INOISE ONOISE
*  SOURCES
VDD  VDD 0  DC   1.65V
VSS  VSS 0  DC  -1.65V
VGD  GND 0  DC   0V
*
VIN INP 0 DC 0V AC 1
*  ANALYSIS NETWORK
RI  INM GND  BIAS OP=100G DC=100G AC=1K   NOISE=0
RF  INM OUT  BIAS OP=1U   DC=1U   AC=100G NOISE=0
*  LOAD
CL  OUT GND  300P
RL  OUT GND  16
*  MAIN CIRCUIT  
*
.INCLUDE Netlist.Filename
*
.END
************************************************
*
************************************************
* PSRR ANALYSIS         
*******************************************
*  DEVICE MODELS
.INCLUDE TIModel3Vp6um  NOPRINT
*  ANALYSIS
.OPTIONS NUMDGT=12 LVLSUB=0 TOL=1U OP DCNODE
+ DISPFREQ=0 
.AC DEC 100 1 100MEG
.PRINT AC VDB(OUT)  
.PUNCH AC VDB(OUT) 
*  SOURCES
VDD  VDD 0  DC   1.65V AC 1
VSS  VSS 0  DC  -1.65V
VGD  GND 0  DC   0V
*        
VIN INP 0 DC 0V 
*  ANALYSIS NETWORK
RF  INM OUT  1
*  LOAD
CL  OUT GND  300P
RL  OUT GND  16
*  MAIN CIRCUIT  
*
.INCLUDE  Netlist.Filename
*
.END
************************************************
*
************************************************
* COMMON-MODE GAIN        
*******************************************
*  DEVICE MODELS
.INCLUDE TIModel3Vp6um  NOPRINT
*  ANALYSIS
.OPTIONS NUMDGT=12 LVLSUB=0 TOL=1U OP DCNODE
+ DISPFREQ=0 
.AC DEC 100 1 100MEG
.PRINT AC VDB(OUT)
.PUNCH AC VDB(OUT)
*  SOURCES
VDD  VDD 0  DC   1.65V
VSS  VSS 0  DC  -1.65V
VGD  GND 0  DC   0V
*
* CMRR AT MID SUPPLY
VIN1 INM S0 DC 0V AC 1
VIN2 INP  0 DC 0V AC 1
* CMRR AT 1 VOLT ABOVE MID SUPPLY
*VIN1 INM S0 DC 1V AC 1
*VIN2 INP  0 DC 1V AC 1
* CMRR AT 1 VOLT BELOW MID SUPPLY
*VIN1 INM S0 DC -1V AC 1
*VIN2 INP  0 DC -1V AC 1
*  ANALYSIS NETWORK
RF  OUT S0  1M
*  LOAD
RL  OUT GND  16
CL  OUT GND  300P
*  MAIN CIRCUIT  
*
.INCLUDE  Netlist.Filename
*
.END
************************************************
*
************************************************
* SINE WAVE ANALYSIS FOR THD    
**********************************************
*  DEVICE MODELS
.INCLUDE TIModel3Vp6um NOPRINT  
*  ANALYSIS
.OPTIONS NUMDGT=8 LVLSUB=0 TOL=1N OP DCNODE
+ DISPFREQ=0 
.TRAN 500NS 16MS FOUR_FREQ=1K FOUR_NCOEFF=12
.FOUR  V(OUTP,OUTM POS,NEG) 
.PUNCH TR V(OUTP,OUTM POS,NEG OUTP OUTM)
*  SOURCES
VDD  VDD  0  DC  1.65V
VSS  VSS  0  DC -1.65V
VAG  GND  0  DC  0V
*
VIN  POS NEG SIN 0V 1.25V 1KHZ
RCM1 NEG GND 1
RCM2 POS GND 1
*
*  LOAD NETWORK
RL OUTP OUTM 32
CL OUTP OUTM 150P 
*
*  MAIN CIRCUIT
*  FEEDBACK NETWORK
RF1 N101 OUTP  5K
RI1 N101 NEG   5K
RF2 N102 GND   5K
RI2 N102 POS   5K
XA1 N101 N102 OUTP VDD VSS AMP
RF3 N103 OUTM  5K
RI3 N103 POS   5K
RF4 N104 GND   5K
RI4 N104 NEG   5K
XA2 N103 N104 OUTM VDD VSS AMP
*
*  SUBCIRCUIT
.SUBCKT AMP INM INP OUT VDD VSS 
.INCLUDE  Netlist.Filename
.ENDS 
*
.END