* AMPLIFIER FOR UTD CLASS 
*********************************
*  DEVICE MODELS
.INCLUDE TIModel5V1um     NOPRINT
.INCLUDE NwellDiodeModel  NOPRINT
*  ANALYSIS
.OPTIONS NUMDGT=8 LVLSUB=0 TOL=1U 
+ OP DCNODE CAPMAX=1
.AC DEC 10 1 1G
.PRINT AC VDB(OUT) VP(OUT) 
.PUNCH AC VDB(OUT) VP(OUT) 
*  SOURCES
VDD VDD 0  DC   5V
VSS VSS 0  DC   0V
*        
IB BIAS VSS DC  10UA
*
VIN INP 0 DC 2.5V AC 1 
*  ANALYSIS NETWORK
RF  INM OUT  1G
CF  INM VSS  1M
*  PARASETIC
DW  VSS N33  DJAREANW AREA=8208
*  LOAD
CL  OUT VSS  10PF
*  MAIN CIRCUIT
RC N22 N44 600
CC N44 OUT 4PF
M1 N11  INM  N33 N33  PCH  W=200  L=4  AD=#W*3# AS=AD PD=#W*2+6# PS=PD
M2 N22  INP  N33 N33  PCH  W=200  L=4  AD=#W*3# AS=AD PD=#W*2+6# PS=PD
M3 N11  N11  VSS VSS  NCH  W=75   L=3  AD=#W*3# AS=AD PD=#W*2+6# PS=PD
M4 N22  N11  VSS VSS  NCH  W=75   L=3  AD=#W*3# AS=AD PD=#W*2+6# PS=PD
M5 OUT  N22  VSS VSS  NCH  W=750  L=3  AD=#W*3# AS=AD PD=#W*2+6# PS=PD
M6 OUT  BIAS VDD VDD  PCH  W=600  L=6  AD=#W*3# AS=AD PD=#W*2+6# PS=PD
M7 N33  BIAS VDD VDD  PCH  W=120  L=6  AD=#W*3# AS=AD PD=#W*2+6# PS=PD
M8 BIAS BIAS VDD VDD  PCH  W=40   L=6  AD=#W*3# AS=AD PD=#W*2+6# PS=PD
*
.END